Калькулятор

Логарифмическая линейка - 100%. Ну может в экселе еще есть такие настройки.

Посмотрите страничку
[ссылка заблокирована по решению администрации проекта]

В Ecxel очень удобно обрабатывать угловые величины при помощи пользовательских функций, которые можно оформить или как модуль в VBA или как надстройку.
Формат ввода угловых величин - ГрадусыТочкаДесятичнаяМинутыСекундыДолиСекунд (D.mmss),
как минуты, так и секунды должны содержать по две цифры, если за ними есть значащие цифры.
Машинное представление и обработка угловых величин выполняется со всеми введенными значащими цифрами минут, секунд и долей секунд. Вывод в ячейку осуществляется выбором формата пользователя: Формат, Ячейки, Число, Все форматы.

В новой книге Excel нужно открыть редактор VBA, в окне VBAProject выделить эту книгу и присоединить к ней модуль (Insert - Module), все функции скопировать прямо отсюда и вставить в в окно модуля, откомпилировать (Debug - Compile VBAProject). Файл "Сохранить как" под любым именем, тип файла "Надстройка Microsoft Office Excel (*.xla)". В меню: Сервис - Надстройки, следует установить флажок рядом с названием сохраненного файл.

После этого возможны примерно такие функции:
=Sin(radian(254.4128)) 254 градуса 41 минута 28 секунд или ссылка на ячейку, содержащую угол в таком же формате,
gradus(radian(254.4128)+radian(254.4128)) сумма двух углов в формате ввода,
dist(x1;y1;x2;y2) расстояние между двумя точками с координатами x1;y1;x2;y2, или ссылки,
gradus(direct(x1;y1;x2;y2)) дирекционный угол (в градусах минутах секундах ) между точками x1;y1;x2;y2. Любое сочетание и вложение во все функции Excel.
---------------------------------------------------------------------------------------------------------------------------

Public Const pi = 3.14159265358979
Public Const delta = 0.00000000001
'
'Перевод углов в формате D.mmss в радианы
Function Radian(Grad As Double) As Double
If Grad >= 0 Then
Grad = Grad + delta
Else
Grad = Grad - delta
End If
g = Fix(Grad)
mm = (Fix((Grad - g) * 100)) / 60
ss = (Grad * 100 - Fix(Grad * 100)) / 36
Radian = (g + mm + ss) / 180 * pi
End Function

'Перевод углов из радиан в формат D.mmss.
Function Gradus(Rad As Double) As Double
Grad = Rad * 180 / pi
g = Fix(Grad)
mm = Fix((Grad - g) * 60) / 100
ss = ((Grad - g) * 60 - Fix((Grad - g) * 60)) * 0.006
Gradus = g + mm + ss
If Gradus >= 0 Then
Gradus = Gradus + delta
Else
Gradus = Gradus - delta
End If
End Function

'Вычисление дирекционного направления от точки 1 на точку 2, параметрами функции служат координаты х1,у1,х2,у2.
Function Direct(x1 As Double, y1 As Double, _
x2 As Double, y2 As Double) As Double
dX = x1 - x2
dY = y1 - y2
S = Sqr(dX ^ 2 + dY ^ 2)
If dY >= 0 Then
Direct = Application.Acos(dX / S) + pi + delta
Else: Direct = Application.Acos(dX / S) * -1 + pi + delta
End If
If Direct >= pi * 2 Then
Direct = Direct - pi * 2
End If
End Function

'Вычисление расстояния между двумя точками
Function Dist(x1 As Double, y1 As Double, _
x2 As Double, y2 As Double) As Double
dX = x1 - x2
dY = y1 - y2
Dist = Sqr(dX ^ 2 + dY ^ 2)
End Function